I comandi sono le istruzioni da eseguire all’esecuzione del FlowScript. È possibile inserire uno o più comandi, con o senza condizione. Ogni comando deve terminare con il carattere “;” (punto e virgola).

I comandi possibili sono:

• Funzione GoTo (salto)
• Funzione GoToRnd (salto random)
• Funzione Ot (fuori target)
• Assegna valore a campo del nominativo 
• Assegna risposte
• SetVariable (assegnazione campi nominativo e risposte avanzata)

GoTo

Salta alla pagina o domanda specificata.

Esempio salto semplice:

goto(P3);

salta alla pagina P3.

Esempio salto con sequenza:

goto(P3, P5, P10);

salta alla pagina P3, poi alla pagina P5 e pi alla pagina P10.

GoToRnd

Propone le pagine o domande specificate in ordine casuale, concludendo sempre con la pagina o domanda specificata come ultimo parametro.

Per esempio:

gotornd(P5, P6, P10);

Propone le pagine P5 e P6 in ordine casuale poi conclude con la pagina P10.

Ot

Manda il nominativo in corso di intervista fuori target.

Esempio fuori target con condizione:

if(Q1==1 && Q2==3) ot();

Se alla domanda Q1 è selezionata la risposta con codice 1 e alla domanda Q2 è selezionata la risposta con codice 3, vai fuori target

Assegna valore al campo del nominativo

Consente di assegnare un valore ad un qualsiasi campo del nominativo.

Esempio:

{MarcaAuto} = Jaguar;

Assegna “Jaguar” al campo del nominativo MarcaAuto.

Esempio con condizione:

if (Q1==3 && Q2==1) {Abbonamento} = Netflix;

Se alla domanda Q1 è selezionata la risposta con codice 3 e alla domanda Q2 è selezionata la risposta con codice 1, assegna “Netflix” al campo del nominativo Abbonamento.

Assegna risposta

Consente di assegnare una risposta ad una qualsiasi risposta del questionario.

Esempio selezione risposta:

Q15 = 3;

Seleziona la risposta con codice 3 della domanda Q15.

Esempio selezione risposta multipla:

Q15 = '3,4,8';

Seleziona le risposta con codici 3, 4 e 8 della domanda Q15

Esempio valorizzazione risposta aperta di una domanda:

[Q12] = 'sono molto soddisfatto';

Valorizza la risposta aperta della domanda Q12.

Le condizioni permettono di specificare il caso in cui uno o più comandi devono essere eseguiti. Una condizione, nella sua forma più semplice, è costituita dall’istruzione if e da un’espressione di confronto ed è poi seguita dal comando da eseguire nel caso che la condizione risulta vera.

if(Q1==1) ot();

Se alla domanda Q1 è stata selezionata la risposta con codice 1, vai fuori target.

È possibile utilizzare diversi simboli di confronto e gli operatori logici per concatenare più condizioni.

if(Q1>5 && Q2!=1) goto(P5);

Se alla domanda Q1 è stata selezionata una risposta con codice maggiore di 5, e alla domanda Q2 non si è selezionata la risposta con codice 1, vai alla pagina P5.

È possibile utilizzare espressioni con più fattori per effettuare calcoli algebrici o per concatenare testo di risposte aperte, campi del nominativo e stringhe.

if([Q1]+[Q2]<100) goto(P5);

Se la somma del numero inserito alla risposta aperta delle domande Q1 e Q2 è minore di 100, vai alla pagina P1.

Approfondiamo tutti gli argomenti necessari per costruire condizioni di ogni complessità.

• Simboli di confronto
• Operatori logici
• if…then (per specificare comandi da eseguire su condizione vera)
• if…then…else (per aggiungere comandi da eseguire su condizione falsa)
• while (esegue i comandi fino a che la condizione non diventa vera)
• Elenco funzioni utilizzabili nelle condizioni

Simboli di confronto

I simboli di confronto utilizzabili nelle espressioni delle condizioni sono:

• == uguale
• != diverso
• < minore
• > maggiore
• <= minore uguale
• >= maggiore uguale

Operatori logici

Le condizioni possono essere combinate tra loro utilizzando le parentesi e gli usuali operatori logici:

• && e
• || o
• ! negazione

Esempio:( Q1==1 || Q1==2) && ( Q2==1||Q2==2 )

Se alla domanda Q1 è stata selezionata l’opzione con codice 1 oppure con codice 2, e alla Q2 è stata selezionata la risposta con codice 1 oppure 2.

( !Q1==1 ) || ( (Q2== 1 || Q2==2) && (Q3==1||Q3==2) )

Se la condizione “Q1 uguale a 1” non è vera, oppure se alla domanda Q2 è stata selezionata l’opzione con codice 1 oppure con codice 2, e alla Q3 è stata selezionata la risposta con codice 1 oppure 2.

If…then

L’istruzione if…then consente di impostare la condizione in cui uno o più comandi devono essere eseguiti.

if(condizione) comando;

Se la condizione è vera esegui il comando.

Esempio:

if(Q8==3 && [Q2]<18) ot();

Se alla domanda Q8 è stata selezionata l’opzione con codice 3 e alla risposta aperta della domanda Q2 è stato indicato un valore minore di 18, vai fuori target.

Esempio di condizione con più comandi:

if(Q2==3 && Q2!=1) { {Auto_Posseduta}=nessuna; ot(); }

Se alla domanda Q2 è stata selezionata l’opzione con codice 3 e alla domanda Q2 non è selezionata l’opzione 1, valorizza il campo del nominativo “Auto_Posseduta” con nessuna, poi vai fuori target.

If…then…else

L’istruzione if…then…else consente di estendere le possibilità dell’istruzione if…then permettendo l’aggiunta di comandi da eseguire nel caso che la condizione risulti falsa.

La sintassi è la seguente:

if(condizione) {comando su condizione vera} else {comando su condizione falsa}

Ad esempio:

if(Q1==1) goto(P2); else goto(P5);

Se alla domanda Q1 è stata selezionata la risposta con codice 1, vai alla pagina P2, altrimenti (ossia se la condizione è falsa), vai alla pagina P5.

While

While consente di ripetere uno o più comandi fino a che la condizione è vera. L’istruzione while permette quindi di fare loop nel FlowScript. Il suo utilizzo è generalmente limitato a necessità particolarmente complesse. Questa funzione non va confusa con i cicli di sezione del questionario.

La sintassi è la seguente:

while(condizione) comando;

Ad esempio:

{j}=0; 
while ({j} <= {i})
	{
		{totale}= {totale}+[Q1][{j}];
		{j}++;
	}

Assegna alla variabile j il valore 0.

Se il valore della variabile j è minore del valore della variabile i, valorizza il campo totale sommando il valore precedente del campo totale + la cifra inserita alla domanda aperta Q1 di j, quindi incrementa il campo j di 1.

Queste funzioni sono state sviluppate per la gestione di alcune particolari eccezioni e sono utilizzabili sia all’interno di condizioni che all’interno di comandi. Il loro utilizzo è generalmente limitato a necessità particolarmente complesse.

Shorthand if…then…else

In FlowScript è possibile utilizzare l’istruzione if…then…else anche nella forma detta “shorthand”. Questa forma è indispensabile per utilizzare le condizioni all’interno di altri comandi o per inserire il testo dinamico nei testi del questionario. Tecnicamente, la forma if “shorthand”, permette di inserire una condizione all’interno di funzioni che accettano solo espressioni. Nonostante la diversa sintassi la logica e il funzionamento non differiscono dal normale funzionamento dell’ if…then…else.

condizione ? espressione_condizione_vera : espressione_condizione_falsa

Ad esempio:

(Q1==1)?'privato':'azienda'

Se alla domanda Q1 è selezionata l’opzione con codice 1, restituisci la stringa “privato”, altrimenti “azienda”.

(Q1==1)?{codice_fiscale}:{partita_iva}

Se alla domanda Q1 è selezionata l’opzione con codice 1, restituisci il valore del campo del nominativo “codice_fiscale”, altrimenti restituisci il valore del campo “partita_iva”.

([Q1]>1)?'quanti anni hanno i tuoi figli':'quanti anni ha tuo figlio'

Se alla risposta aperta della domanda Q1 si è scritto un numero maggiore di 1 (numero di figli), mostra il testo della domanda al plurale, altrimenti al singolare.

In questo esempio viene mostrato come comporre condizioni if else “shorthand” annidate.

( [Q1]>=4 ) ? 'positivo' : ( [Q1]<=2 ) ? 'negativo' : ( [Q1]==3 ) ? 'neutro' : ' '

Se alla risposta aperta della domanda Q1 è stato inserito un valore maggiore o uguale 4, restituisci la stringa “positivo”, altrimenti controlla se è stato inserito un valore minore o uguale 2 e in questo caso restituisci la stringa “negativo” altrimenti controlla se è stato inserito il valore 3 e in questo caso restituisci la stringa “neutro” altrimenti restituisci la stringa vuota.

Il FlowScript privilegia la velocità di scrittura e la semplicità delle espressioni a discapito dell’ortodossia del linguaggio. Questo causa alcune particolarità che  possono confondere gli utenti che hanno esperienza con altri linguaggi di programmazione.

Stringa con o senza apici, quali sono le differenze?

La sintassi completa e corretta delle stringhe prevede l’utilizzo di apici. Se la stringa è formata da una singola parola (ossia senza spazi), gli apici possono essere omessi.

Pertanto la sintassi [D1]==Marco è equivalente a [D1]=='Marco'.

La condizione [D1]=='molto soddisfatto' non può essere scritta senza apici in quando sono necessari per determinare l’inizio e la fine della stringa.

Asimmetria dei confronti

Gli elementi che si confrontano nelle condizioni (vale a dire gli elementi prima e dopo l’operatore di confronto) NON sono identici. Quello dopo l’operatore di confronto è interpretato sempre come stringa, mentre quello che precede l’operatore, se è una stringa libera (ovvero senza apici), è interpretato come codice domanda.

Per esempio la condizione D1==1 significa “verifica se alla domanda con codice D1 è stata data una risposta con codice 1”. Se inverto l’ordine degli elementi ottengo la condizione 1==D1 che significa “verifica se alla domanda con codice 1 è stata data una risposta con codice D1” che è radicalmente diverso.

Per cui bisogna sempre considerare che i confronti NON sono, in generale, invertibili.